Curl Global Community - Baison log

待機サーバと同期する際の判断条件

Thu, 22 Jan 2015 09:28:12 +0000

★point
sc コマンドでWindowsサービスの管理を行える

ある本番サーバ環境と、その待機サーバの間で、夜間バッチにて、データベースの同期をとる際、
単純に、本番のDBからエクスポートしたダンプファイルを、待機サーバに送り、インポートする、
つまり、単純に上書きをするとします。

しかし、もし障害が発生し、待機側のDBが「正しい」状態になっていたら、
本番サーバから上書きしてはいけないことになります。
その「上書きしていいかどうか」の判断として、
『本番サーバのサービス（ApacheTomcat）が動いて』いたら、
待機サーバが運用されているものとして、本番から上書きを行わない、
という方式を考えてみました。

この場合に、本番サーバから、待機サーバのサービスの状態を確認するには、
下記のようなコードでいけそうです。

Code:
@Echo Off

Call :DoesRunningService "1  STOPPED"

Call :DoesRunningService "4  RUNNING"

Exit /B

::--------------------------------------

::サービスの状態を確認をするサブルーチン

::--------------------------------------

:DoesRunningServic

    SET service=Tomcat7

    sc \\133.170.235.90 query %service% | FindStr -C:%1>NUL

    If ERRORLEVEL 1 ( Echo %service% : %1 NG ) Else (Echo %service% : %1 OK )

Exit /B

ちなみに、この「sc コマンド」は、サービスの状態だけでなく、
サービスの開始や停止なども行えます。

ちなみに、サービスのインストールは、
.NETのインストール用ユーティリティ（InstallUtil.exe）で、できるみたいです。

例：
"C:\Windows\Microsoft.NET\Framework\v2.0.50727\InstallUtil.exe" サービス名

リモートデスクトップの同時接続数を増やす

Tue, 20 Jan 2015 04:37:58 +0000

★point
気を使うより、数増やせ

下記サイトを参考にして、リモートデスクトップの同時接続数を増やすことができます。

■1 つの接続で実行可能な同時リモート接続数を構成する
http://technet.microsoft.com/ja-jp/libra...53380.aspx

これで、他の作業者の顔色を窺わずとも、気軽にサーバにログインできになります。

WebLogic で Curl を動かす

Thu, 08 Jan 2015 00:02:32 +0000

★point
MIMEの設定を忘れずに

WebLogic で新しくドメインを追加して、Curlアプリケーションをデプロイすると、
「Error:InvalidAppletException: content-type''はサポートされていません。」
というエラーが表示されるようになってしまいました。

これまでのドメインでは動いていたのになんでだろうと、過去の設定作業を思い出してみると、
MIMEタイプの設定が必要だったことを忘れていました。

■MIME
Oracle\Middleware\user_projects\domains\<ドメイン名>\config
mimemappings.properties

内容
curl=text/vnd.curl
dcurl=text/vnd.curl.dcurl
scurl=text/vnd.curl.scurl
mcurl=text/vnd.curl.mcurl
pcurl=application/vnd.curl.pcurl
car=application/vnd.curl.car

私の環境では、画像のPNGファイルとか、ワンダフルレポートという帳票ツールも使っていたので、下記の記述も追加していました。
png=image/png
wfr=application/octet-stream
wfi=application/octet-stream
wff=application/octet-stream

ちなみに、デプロイ対象のフォルダの下には、Curlのソースだけでなく、WEB-INFフォルダを作成し、web.xmlがないと、
WebLogicの管理コンソールでデプロイ対象として認識されないみたいです。
私の環境では下記2ファイルを置いていました。

■web.xml

Code:

sccess

index.html

index.htm

index.jsp

default.html

default.htm

default.jsp

■weblogic.xml

Code:

PUBLIC "-//BEA Systems, Inc.//DTD Web Application 8.1//EN"

"http://www.bea.com/servers/wls810/dtd/weblogic810-web-jar.dtd"

ルート名

なお、mimemappings.propertiesがなくても、
web.xml にMIMEを記述すれば行けるみたいです。
例

curl

=text/vnd.curl

バッチプログラムの勉強

Thu, 25 Dec 2014 05:44:55 +0000

★point
餅は餅屋。バッチに任せられるものは任せよう。

不要ファイル削除等の日時処理や、メンテナンスのために、
バッチプログラムをいろいろと組む必要が出てきたので、
参考になったサイト等をメモ。

コマンドプロンプトは難しいイメージがありますが、
勉強して使えるようになってくると便利ですね。

■基本的なバッチの書き方
http://d.hatena.ne.jp/language_and_engin...MSDOSorBAT
勉強になりました

■コマンドプロンプトの変数
http://pf-j.sakura.ne.jp/program/dos/dos...ercent.htm
知らないと結構悩む

■環境変数の遅延展開
http://d.hatena.ne.jp/ladybug/20090530/p1
知らないとドツボにはまる

■for文
http://www.atmarkit.co.jp/ait/articles/0...ws002.html
実行結果の取得とか、単純なループ処理以外に使える、
というか、forを理解しないとバッチは進まない

■タスクスケジューラの管理
http://hisk2tmem.blog61.fc2.com/blog-entry-48.html
最初、相手先を<\\IP>で指定できることに気付かなかった
サーバ間でバッチを呼び出し合うのに利用

■サービスの作成や実行 sc コマンド
http://win-cmd.seesaa.net/article/85809065.html
非常用のサーバを準備する際など、複数のサービスを起動できる

■コマンドラインから Javascript を実行 mshta コマンド
http://d.hatena.ne.jp/language_and_engin...1224678990
なんでもできすぎて危険、かつ魅惑的なコマンド

「切断したネットワークドライブ」が消えない

Wed, 24 Dec 2014 06:14:22 +0000

★point
ネットワークドライブの割り当ては自動で行う

あるとき、サーバのエクスプローラを開くと、とあるバッチの中で利用している「Z:ドライブ」が、
「切断したネットワークドライブ」と表示され、アイコンに赤バッテンがついている。

なぜだろうと思って、コマンドプロンプトから「net use」と打っても、
「一覧にエントリが存在しません」となる。

そうか、使ってないのか、と思って、再割り当てをしようと、
「net use z: <\\ホストのIP><\ドライブ$> <パスワード> /user:<ユーザ> /persistent:no」
みたいなコマンドを打つと、
今度は「ローカルデバイス名は既に使用されています。」となる。

使っているのか、いないのか、はっきりしてくれよ、と思いながら、
リポジトリの「HKEY_CURRENT_USER\Network\」を確認しても、何もない。
もちろん「net use z: /DELETE」を実行しても、切断したネットワークドライブは残ったまま。

ネットの諸情報を見ると同じ問題で困っている人も多いようで、
確実そうな情報としては、「net use /PERSISTENT:yes」と打ってから、
Windows の再起動を行うと「切断したネットワークドライブ」は消える、とのことなのですが、
サーバをホイホイ再起動するわけにもいきません。

とりあえず、バッチ側で行っていたネットワークドライブの割り当てを、
「net use」コマンドでの直接ドライブ指定ではなく、
「pushd」コマンドで、自動割り当てすることになりました。

ちなみに、「pushd」コマンドで割り当てられたドライブの取得方法はよくわかりませんが、
「pushd」コマンド実行直後は、割り当てられたドライブがカレントディレクトリになるので、
「%CD%」でカレントディレクトリ（＝割り当てらられたドライブ）を取得すればよさそうです。

■pushd
http://www.atmarkit.co.jp/fwin2k/win2kti...pushd.html

■コマンドプロンプトの%について
http://pf-j.sakura.ne.jp/program/dos/dos...ercent.htm

OEM にアクセスできない

Fri, 05 Dec 2014 05:51:41 +0000

★point
　鳴かぬなら、殺してしまえSSL

Oracle をインストールして、データベースを作成後、
Database Console のサービスが立ち上がっているのに、
Oracle Enterprise Manager（OEM）をブラウザで表示しようとすると、
「この Web サイトのセキュリティ証明書には問題があります。」と表示され、
閉じるしか選択肢がない状態になることがある。

Fire Fox でアクセスすれば表示できる場合もあるが、
ある環境ではできなかった。
とりあえず、SSLの設定を外せば、httpでアクセスできるようになるみたい。

以下はSSLを外すための手順

①コマンドプロンプトを起動
②DBコンソールのサービスを止める
emctl stop dbconsole
③SSLの設定を外す
emctl unsecure dbconsole
④DBコンソールのサービスを開始する
emctl start dbconsole
⑤http://ホスト名:ポート/em でアクセスする

ちなみに、戻す時は emctl secure dbconsole

これまでも、最初は警告が表示されてOEMを起動できない、ということはあったのですが、
どうも、Windows Update や、IEのバージョン（現時点の最新11など）のからみで、
発生する問題みたい。

RecordSetでの大量データ

Fri, 05 Dec 2014 05:41:50 +0000

★point
大量データを扱うときは、RecordFieldの数に気をつけろ

ビッグデータといわないまでも、数万件から数十万件のデータを、
Curlで扱いたいということが最近増えてきました。

私が大量データを扱う経験したのは、CSVで作成した元データを、サーバに送って取り込む機能。
通常業務では取り込む対象は数件とのことだったので、1万件程度の負荷テストだけで済ませていました。
しかし、1年に何回か、10万件のデータを取り込む、という運用があるとのことで、
最大データ容量での負荷テストを行ったとたん、メモリ不足でCurlが落ちてしまいました。

最終的には、ファイルを内部で分割しながらサーバとやり取りする仕組みに実装しなおしたことで
問題は解決しましたが、
メモリ消費量の推移がイマイチ納得いかなかったので、
サンプルを作ってテストしてみました。

その内容は以下。
ちなみに、メモリ消費量はタスクマネージャで確認した値です。

フィールド数　　レコード件数/メモリ消費量
　　　　　　　　 3万件　　 6万件　　12万件
　　　　　70　　 30MB　　　60MB　　 120MB
　　　　 140　　 60MB　　 120MB　　 240MB
　　　　 210　　120MB　　 240MB　　 470MB
　　　　 280　　110MB　　 240MB　　 470MB
　　　　 350　　230MB　　 460MB　　 820MB
　　　　 420　　230MB　　 460MB　　 830MB

見てわかるとおり、レコード件数に対しては一定の比率ですが、
フィールド数に対しては、210個と280個、380個と420個の場合に同じメモリ消費量となり、
階段のようなグラフになっていることがわかります。

サンプルの中では、フィールドの物理名の長さを変えたり、
レコードの値設定を、通常の set ではなく、BasicRecord.internal-set-value に変えてみたりと
いくつかのチェックをしましたが、どれも有意な差にはなりませんでした。

大量RecordSetを作る上での一番のポイントはフィールド数であり、
閾値の確認まではしていませんが、
メモリの領域が足りなくなった段階で、倍々で確保する仕組みになっているのかもしれません。

業務仕様上、フィールド数を単純に削減することはできないかもしれませんが、
大量データをRecordSetに取り込む場合は、
フィールド数を意識しておくとよいかもしれません。

Eclipse で実行しているサーバのパスがわからないときは？

Fri, 08 Aug 2014 03:31:13 +0000

新規開発時に、既存のサーバプロジェクトをコピーして再利用すると、
サーバの起動パスがわからなくなることがあります。
そんなときは、下記の方法で確認できます。

■Eclipse で実行しているサーバのパスの確認方法
　①「サーバ」ビューで、対象サーバをダブルクリック
　②「概要」タブが開くので、その下部の「モジュール」タブを選択
　③各リソースのパスが、「パス」カラムに表示されている

「パス」の初期値は、プロジェクトの「\.settings\org.eclipse.wst.common.component」で記述されているぽいので、
修正するには、ここの値を書き換える。

（下記コード10行目の context-root の値）
[code]

[code]

SplashScreen の利用にはお気をつけて

Tue, 08 Jul 2014 07:53:21 +0000

★point
　実行時間の短いサービスでは、SplashScreen を利用するな

現在、ORBを利用したサービス呼び出しを連続で行うと、
結果の返却順番が入れ替わってしまう、という問題が起きています。

■プログラムの前提
　１．サービス名：税計算サービス
　　日付と区分を引数に、対象となる税率を返却する
　２．イベントＡ．日付を表すDateField の ValueFinished で、税計算サービス（TaxService.calc-tax）を呼び出す
　３．イベントＢ．区分を表す RadioFrame の ValueFinished で、税計算サービス（TaxService.calc-tax）を呼び出す
　４．税計算サービスの実行結果を、税率フィールドに表示する

■引数と結果の組み合わせ例
　　日付：2010、区分：消費税　結果：5％
　　日付：2014、区分：消費税　結果：8％
　　日付：2010、区分：外貨　　結果：0％
　　日付：2014、区分：外貨　　結果：0％

■操作手順
　①DateField の日付を2010年から、2014年に変更する
　　（フォーカスアウト等はしていないのでValueFinishedは未発生）
　②RadioFrame のラジオボタンを、消費税から、外貨に変更する
　　（この段階で、DateFieldのValueFinished が発生、次に、RadioFrame のValueFinished が発生する）

■結果
　5回に１回くらいの割合で、税率フィールドに8％と表示される
　※１：上記操作の結果、画面上は「日付：2014、区分：外貨」となっているのにもかかわらず、
　　　　「日付：2014、区分：消費税」（ラジオボタンの変更前の状態）の結果がセットされる
　※２：税率フィールドには、一瞬「0％」と表示されたのち、「8％」が表示される

100%発生するわけではなく、ある程度の割合で発生するので、
明確な原因は不明なのですが、サービス呼び出しの箇所にログを仕掛けたところ、
下記のような処理の順番になっていることがわかりました。

■処理順
　①DateField の ValueFinished イベントで calc-tax が呼び出される
　②RadioFrame の ValueFinished イベントで calc-pay-pln-dt が呼び出される
　　（本来であれば、①の結果を返却してから、サービスが呼ばれるべき！）
　③②の結果が返却される
　④①の結果が返却される
　　（順番が入れ替わることで、不正な結果となってしまう）

これは、DateField のValueFinished で呼び出されたサービスの結果が返却される前に、
RadioFrame のValueFinished イベントが割り込んでいるように見えます。

dispatch-events を記述することでこのような問題が発生する可能性がありますが、
プログラムには、dispathc-events は記述していません。

そこで怪しいと思ったのが、「SplashScreen」です。

現在、サービスの呼び出し時に、下記のようなインタセプタを設定しています。
内容としては、サービス呼び出し時（handle-before-request）に SplashScreen を表示して、
サービス実行後（handle-after-response）に、SplashScreenを閉じる、という処理になっています。

このサービス呼び出し時の処理のなかで、対象のサービスの場合だけ、SplashScreenを表示しない、
という処理を入れると、この問題は再現しなくなりました。

SplashScreen のコードはOPEN-CONTROLS にもないので、確実なことは言えませんが、
もしかすると、SplashScreen.setup の内部でdispatch-events のような処理が実行されており、
そのため、DateField とRadioButton のValueFinished イベント割り込みが発生しているのではないか、
と私は判断しています。

同様の問題が発生している環境があれば、この辺りを疑ってみるとよいかも知れません。

もし詳しい方がいらっしゃれば情報提供いただけるとありがたいです。

Code:
||サービスコール時に、プログラムIDが指定されているかどうかを判断するインタセプタ

{define-class public InitializeServiceInterceptor {inherits ClientInterceptor}

  ||プログレスバーの表示を無視するサービスの一覧

  ||　共通処理と終了（ログアウト）処理は無視する

  field exclusion-methods:{Array-of String} =

      {{Array-of String}

         "lightning-service"

      }

  ||プログレスバー処理を行う対象のメソッドかどうかを調べる

  ||アプリケーション終了時にはサブアプレットの生成ができないので、

  ||終了時のログアウトだけ、プログレスバーを表示しない

  || また、共通機能からの通信 find-mst-info、find-base-date-info についても表示しない

  {method {get-progress-method?

              methos-name:String ,

              arguments:#FastArray

          }:bool

    {if {self.exclusion-methods.find methos-name} > -1 then

        {return false}

     else

        {if {self.get-common? arguments} then

            {return false}

        }

        {return true}

    }

  }

  {constructor public {default

                          client-filter:{proc-type {AbstractClient}:bool} =

                              {fn client => true}

                      }

    {construct-super client-filter = client-filter}

  }

  ||  handle-before-request　：メソッド実行前の処理を定義できます。

  {method protected open {handle-before-request 

                             http-request-headers:#HttpRequestHeaders,

                             orb-request-hearders:#HashTable,

                             method:Method,

                             arguments:#FastArray

                         }:(http-request-headers:#HttpRequestHeaders, orb-request-headers:#HashTable)

    {if {self.get-progress-method? method.name, arguments} then

        {ProgressView.setup

            title = "サーバ処理",

            footer = "サーバ処理中です．．．"

        }

    }

    {self.print  "[START] " & method.defining-class.name & "." & method.name }

    {if-non-null args = arguments then

        {for arg in args do

            {if not {self.get-common? arguments} then

                {self.print "INPUT-DTO = " & {String {type-of arg}}}

            }

        }

    }

    def (ret-http-request-headers:#HttpRequestHeaders, ret-orb-request-headers:#HashTable) =

        {super.handle-before-request

            http-request-headers,

            orb-request-hearders,

            method ,

            arguments

        }

    {return ret-http-request-headers, ret-orb-request-headers}

  }

  ||  handle-after-response　：メソッド実行後の処理を定義できます。

  {method protected open {handle-after-response

                             header:#HttpResponseHeaders,

                             map:#{HashTable-of any, any},

                             method:Method,

                             arguments:#{FastArray-of any},

                             return-value:any}:(#HttpResponseHeaders, #{HashTable-of any, any})

    {if {self.get-progress-method? method.name, arguments} then

        {ProgressView.destroy}

    }

    {self.print  "[END] " & method.defining-class.name & "." & method.name }

    {return {super.handle-after-response header, map, method, arguments,return-value }}

  }

  ||  handle-exception　：例外発生時の処理を定義できます。

  {method protected open {handle-exception ||throw-advice

                             method:Method,

                             arguments:#FastArray,

                             exception:Exception

                         }:void

    ||{if {self.get-progress-method? method.name} then

    {ProgressView.destroy}

    ||}

    {self.print "[ERROR] " & method.defining-class.name & "." & method.name}

    {type-switch exception

     case rae:RemoteApplicationException do

        {self.print "[ERROR-MESSAGE] " & rae.remote-error.message-id & ":" & rae.remote-error.message}

     case rse:RemoteSystemException do

        {self.print "[ERROR-MESSAGE] " & rse.remote-error.message-id & ":" & rse.remote-error.message}

     else

        {self.print "[ERROR-MESSAGE] " & exception.message & ":" & {type-of exception}}

    }

    ||システム例外が、アプリケーション処理継続不能な処理の場合、

    ||共通的に処理する

    {type-switch exception

     case re:RemoteSystemException do

        {if-non-null re.remote-error, message-id = re.remote-error.message-id  then

            ||タイムアウト、バッチ実行中の処理判断の検討結果に合わせて変更

            {switch message-id

             case SERVER-ERROR-CODE-EXECUTING-BATCH do

                {popup-message "バッチ実行中のためサーバアクセスが拒否されました。\nアプリケーションを終了します。"}

                {self.print "バッチ実行中のためユーザー確認後、アプリケーション終了"}

                {exit}

             case  SERVER-ERROR-CODE-TIMEOUT do

                {popup-message

                    "タイムアウトしました。\nアプリケーションを終了します。"

                }

                {self.print "タイムアウトのためユーザーがアプリケーション終了を判断"}

                {exit}

            }

        }

    }

    {super.handle-exception method, arguments, exception}

  }

  ||  register-interceptor　：Interceptor登録時の処理を定義できます。

  {method protected open {register-interceptor

                             client:AbstractClient

                         }:void

    {super.register-interceptor client}

  }

  || -- private --

  {method private {print str:String}:void

    {output-log-info "[SERVICE] " & str}

  }

}

||インターセプターの登録

{register-orb-interceptors

    {InitializeServiceInterceptor}

}

||プログレスビューとして表示する画面

{import * from CURL.ENGINE.BROWSER}

{def package splash-screen-applet-source:String =

    {stringify

        {curl 8.0 applet}

        {import * from CURL.ENGINE.BROWSER}

        {define-class public CustomSplashScreenSubApplet

          {inherits SplashScreenSubApplet}

          {constructor public {default}

            {construct-super}

            set self.footer-frame.font-size = 11pt

          }

          {method public open {create-main-body}:Graphic

            def vb =  {VBox

                          font-size = 11pt,

                          width=4in,  spacing = 3pt, margin = 4pt,

                          height = 0.7in,

                          border-width = 1pt,

                          border-color = "black",

                          background = "white",

                          hstretch? = true,

                          framelike-stretch? = true,

                          self.title-frame,

                          self.progress-bar-frame,

                          self.footer-frame,

                          ||透明度を設定する

                          {on AttachEvent at vb:VBox do

                              def view = vb.parent.parent asa View

                              {view.set-opacity 0.7 asa float}

                          }

                      }

            {vb.add-event-handler

                {context-popup

                    menu-pane={MenuPane

                                  {MenuAction

                                      label="閉じる",

                                      {on Action do

                                          {exit}

                                      }

                                  }

                              }

                }

            }

            {return

                vb

            }

          }

        }

        {after 0s do

            {CustomSplashScreenSubApplet}

        }

    }

}

||

{define-class public ProgressView

  ||このパラメータが true の間は、別のプログレスビューを表示したり、閉じたりしない

  ||複数のサービスをfor文で呼ぶ場合などで、その処理全体の時間中にプログレスビューを表示したい場合に利用してください。

  ||{with} マクロを使ってこのフラグを true に設定することを強くお勧めします。

  let public ignore?:bool = false

  ||プログレスバーが表示されているかどうかを保持する変数

  let private show?:bool = false

  {define-proc public {set-progress-bar-indeterminate}:void

    {if {this-class}.ignore? then

        {return}

    }

    {if ProgressView.show? then

        {SplashScreen.set-progress-bar-indeterminate}

    }

  }

  {define-proc public {set-progress-bar-value val:double}:void

    {if {this-class}.ignore? then

        {return}

    }

    {if ProgressView.show? then

        {SplashScreen.set-progress-bar-value val}

    }

  }

  {define-proc public {set-progress-bar

                          min:double = 0.0,

                          max:double = 100.0,

                          value:double = min}:void

    {if {this-class}.ignore? then

        {return}

    }

    {if ProgressView.show? then

        {SplashScreen.set-progress-bar min = min, max = max, value = value}

    }

  }

  {define-proc public {show}:void

    {if {this-class}.ignore? then

        {return}

    }

    {if not ProgressView.show? then

        {SplashScreen.show}

        set ProgressView.show? = true

    }

  }

  {define-proc public {setup

                          title:String = "お待ちください",

                          footer:String = "処理の終了を待っています ...",

                          image-url:#Url = null,

                          width:Distance = 0m,

                          height:Distance = 0m,

                          splash-applet-url:#Url =  {string-url splash-screen-applet-source},

                          delay:Time = .3s

                      }:void

    {if {this-class}.ignore? then

        {return}

    }

    {ProgressView.destroy}

    {if not ProgressView.show? then

        {try

            {SplashScreen.setup

                title = title,

                footer = footer,

                image-url = image-url,

                width = width,

                height = height,

                splash-applet-url = splash-applet-url,

                delay = delay

            }

            {SplashScreen.set-progress-bar-indeterminate}

         catch e:Exception do

        }

        set ProgressView.show? = true

    }

  }

  {define-proc public {set-footer

                          footer:String,

                          halign:any = "left",

                          font-family:String =  "MS Gothic",

                          font-size:Distance = 0m,

                          font-weight:any = null,

                          color:String = "black"

                      }:void

    {if {this-class}.ignore? then

        {return}

    }

    {SplashScreen.set-footer

        footer,

        halign = halign,

        font-family = font-family,

        font-size = font-size,

        font-weight = font-weight,

        color = color

    }

  }

  {define-proc public {destroy}:void

    {if {this-class}.ignore? then

        {return}

    }

    {try

        {SplashScreen.destroy}

     catch e:Exception do

    }

    set ProgressView.show? = false

  }

}

SQLステートメントとパラメータを組み合わせて実行可能なSQLを整形する

Thu, 03 Jul 2014 09:57:52 +0000

私は、サーバの開発で iBatis を利用することが多いのですが、
log4j を利用することで、SQLのステートメントとパラメータの両方が、
出力されるようになっています。

■出力例
yyyy-mm-dd hh:mms,mmm DEBUG [java.sql.Connection] [http-8080-2] [********************] - {conn-NNNNNNN} Preparing Statement: SELECT * FROM EMP_MST WHERE EMP_CD = '?'
yyyy-mm-dd hh:mms,mmm DEBUG [java.sql.PreparedStatement] [http-8080-2] [*******************] - {pstm-NNNNNN} Parameters: [A0001]

テストの際などに、サーバ処理の中で利用されたSQLを、
改めて、DBに対して直接投げてみたい、ということがよくあります。
そのためには、このステートメントとパラメータを組み合わせてSQLを作り直す必要があるのですが、
パラメータ数が多いといちいち「?」を置換して整形するのが面倒なので、
下記のようなサンプルで組み立てるようにしています。

Code:
{curl 8.0 applet}

{curl-file-attributes character-encoding = "utf8"}

{import * from CURL.DESKTOP.CLIPBOARD}

{def sql-ta:TextArea =

    {TextArea

        ||width = {make-elastic preferred-size = 1in},

        height = {make-elastic preferred-size = 1in}

    }

}

{def param-ta:TextArea =

    {TextArea

        ||width = 7in,

        height = {make-elastic preferred-size = 0.5in}

    }

}

{def comp-ta:TextArea =

    {TextArea

        ||width = 7in,

        height = {make-elastic preferred-size = 0.5in}

    }

}

{define-proc {get-type-list

                 index:int,

                 val:String,

                 params:StringArray

             }:DropdownList

    || ■CHAR

    || ■NUMBER

    || ■VARCHAR2

    || ■TIMESTAMP

    || ■DATE

    def dl =  {DropdownList

                  name = val,

                  user-data = index,

                  "文字列",

                  "数値",

                  {on ValueChanged at dl:DropdownList do

                      {switch dl.value

                       case  "文字列" do

                          set params[dl.user-data asa int] = "\'" & {dl.name.trim-clone} &  "\'"

                       else

                          set params[dl.user-data asa int] = {dl.name.trim-clone} asa String

                      }

                  }

              }

    {if {String {val.to-int}} == val then

        {dl.set-value-with-events "数値"}

     elseif  {String {val.to-double}} == val then

        {dl.set-value-with-events "数値"}

     else

        {dl.set-value-with-events "文字列"}

2014-07-03 16:24:18.554999   START:会計年月日　値確定

2014-07-03 16:24:18.563000  DATE  20140413

2014-07-03 16:24:18.570000  PAY-DV  1

[info] #2014/07/03 16:24:18.579# - [SERVICE] [START] DisPayPlnDtService.calc-pay-pln-dt

[info] #2014/07/03 16:24:18.582# - [SERVICE] INPUT-DTO = DisInCalcPayPlnDtDto

[info] #2014/07/03 16:24:18.582# - [SERVICE] PROGRAM-ID = SCRD2010

2014-07-03 16:24:18.746000   START:支払区分　値確定

2014-07-03 16:24:18.848000  DATE  20140703

2014-07-03 16:24:18.848000  PAY-DV  3

[info] #2014/07/03 16:24:18.850# - [SERVICE] [START] DisPayPlnDtService.calc-pay-pln-dt

[info] #2014/07/03 16:24:18.850# - [SERVICE] INPUT-DTO = DisInCalcPayPlnDtDto

[info] #2014/07/03 16:24:18.850# - [SERVICE] PROGRAM-ID = SCRD2010

[info] #2014/07/03 16:24:18.932# - [SERVICE] [END] DisPayPlnDtService.calc-pay-pln-dt

2014-07-03 16:24:18.933999   END:支払区分　値確定

[info] #2014/07/03 16:24:19.055# - [SERVICE] [END] DisPayPlnDtService.calc-pay-pln-dt

2014-07-03 16:24:19.065000   END:会計年月日　値確定

    }

    {return dl}

}

{def type-tbl =

    {Table

        ||height = {make-elastic preferred-size = 1pt},

        ||valign = "top",

        columns = 4}

}

{def formed-params-by-type:StringArray = {StringArray}}

{def parse-cb =

    {CommandButton

        label = "解析",

        {on Action do

            {type-tbl.clear}

            {formed-params-by-type.clear}

            {type-tbl.add "No."}

            {type-tbl.add "Column"}

            {type-tbl.add "Value"}

            {type-tbl.add "Type"}

            def split-sql = {sql-ta.value.split split-chars = '?'}

            def params = {param-ta.value.split split-chars = ','}

            {for s in params do

                {formed-params-by-type.append {s.trim-clone}}

            }

            {for s key index:int in params do

                let col:String = ""

                def tmp-ary = {split-sql[index].split}

                ||カラム名を探すため、まず。後ろから = を探す

                def find-equal-index =

                    {tmp-ary.find "=", search-direction = SearchDirection.backward}

                {if find-equal-index > -1 then

                    def find-column-index =

                        {tmp-ary.find

                            "",

                            ||空白では「ない」ものを検索

                            equality-proc = {proc {s1:String, s2:String}:bool

                                                {if s1 == s2 then

                                                    {return false}

                                                 else

                                                    {return true}

                                                }

                                            },

                            starting-index = find-equal-index - 1,

                            search-direction = SearchDirection.backward}

                    {if find-column-index> -1 then

                        set col = tmp-ary[find-column-index]

                    }

                }

                {type-tbl.add index + 1}

                {type-tbl.add col}

                {type-tbl.add s}

                {type-tbl.add {get-type-list index, s, formed-params-by-type }}

            }

        }

    }

}

{def replace-cb =

    {CommandButton

        label= "置換",

        {on Action do

            {if not sql-ta.value.empty? then

                def split-sql = {sql-ta.value.split split-chars = '?'}

                let comp-sql:String = ""

                {for s key index:int in formed-params-by-type do

                    set comp-sql = comp-sql & split-sql[index]  & s

                }

                set comp-sql = comp-sql & split-sql[split-sql.size - 1]

                set comp-ta.value = comp-sql

            }

        }

    }

}

{def copy-cb =

    {CommandButton

        label= "クリップボードへコピー",

        {on Action do

            def clip = {Clipboard.get-system-clipboard }

            {clip.set-string comp-ta.value }

        }

    }

}

{View

    title = "SQL解析",

    height = 8in,

    width  = 8in,

    hstretch? = true,

    || この{Frame}を置き換えて使用してください

    {Frame

        hstretch? = true,

        {VBox

            halign = "center",

            margin = 5pt, spacing = 3pt,

            {GroupBox

                label = "■SQL Templete",

                height = null,

                sql-ta

            },

            {HBox

                {GroupBox

                    label = "■Parameter",

                    param-ta

                },

                {GroupBox

                    label = "■Type Select",

                    {ScrollBox

                        hstretch? = true,

                        vstretch? = true,

                        {VBox

                            hstretch? = true, type-tbl, {Fill}}

                    }

                }

            },

            {HBox spacing = 5pt, parse-cb, replace-cb, copy-cb},

            {GroupBox

                label = "■Executable SQL",

                comp-ta

            }

        }

    },

    visibility = "normal",

    {on WindowClose do

        {exit}

    }

}

■使い方
①「SQL Templete」のテキストエリアにステートメントを張り付ける
②「Parameter」のテキストエリアにパラメータを張り付ける
③「解析」ボタンを押す
④必要に応じて「Type Select」に表示される型と値の組み合わせを修正する
⑤「置換」ボタンを押して、ステートメントとパラメータを整形します
⑥「Executable SQL」に出力されたSQLを利用する
　（「クリップボードへコピー」ボタンでコピー可能）

もしかすると、SQL Developer などのツールであれば、
もっとうまくやってくれる機能がありそうな気もしますが・・・。

Oracle のパスワードを忘れたら

Thu, 19 Jun 2014 01:23:36 +0000

★point
　OracleにはOS認証でもログインできます
　OS認証できれば、パスワード忘れてもへっちゃらです

SYSユーザなどのパスワードを忘れてしまっても、DBサーバにログインできるのであれば、
「OS認証」という機能でログインすることで、パスワードが変更できるので問題なし。
いや、これも、DBを長く使っている方であれば当たり前の知識なんだろうなとは思いますが、
今回初めて知ったのでメモです。

■OS認証とは
https://blogs.oracle.com/oracle4engineer...use_osauth

OSユーザの所属グループの設定が正しければ、
下記の手順でパスワードを変更できます。

①DBサーバにリモートデスクトップ等でログイン
②コマンドプロンプトを立ち上げる
③ログイン先のSIDを環境変数「ORACLE_SID」にセット
　set ORACLE_SID=[対象のSID]　※１
④SQLPLUSコマンド実行
　sqlplus /nolog
⑤OS認証でログイン
　conn / as sysdba
⑥SYSユーザのパスワードを変更
　ALTER USER SYS IDENTIFIED BY [new_password] ;

※１
「ORACLE_SID」はレジストリに登録されているキーで、
単純にOS認証でログインすると、このキーに登録されているSIDにログインしてしまう。
値は、最後に作成したSIDが入っているっぽい。
そのため、SQLPLUSに入るまえに、ログインしたいIDを、
setを使って環境変数に一時登録しておくことで、自動的に対象インスタンスにログインできる。

⑥の前に、select * from v$instance; でログイン先のSID名が正しいか確認すると、安全。

マスタ検索フレームワーク

Fri, 23 May 2014 10:41:39 +0000

★point
　開発工数の削減には、汎用的なマスタ検索機能の提供が効果的、かも

「某マスタから、入力したコードを条件にして検索する」というような処理は、
業務システムであれば避けることはできない頻出機能です。

開発方針によっては、マスタ検索も含めて、業務画面の実装に任せる、
という考え方もありえると思いますが、
共通部品として提供できれば、システム開発全体の工数を抑えることができるかもしれません。

そんなわけで、これまでの経験をもとに、シンプルな「マスタ検索フレームワーク」を作成してみました。
アプリケーション基盤として足りない機能などあれば、
アドバイスいただけると嬉しいです。

【基本機能】
テキストフィールドと、カラム（グリッド）の両方で下記の機能を提供する

・入力されたコードが対象のマスタに存在する場合、その一致するレコード情報を取得する
　　　コードと名称が１対１で存在するような一般的なマスタテーブルを前提に、
　　　フィールドに、マスタに存在するコードが入力されたら、名称を補完表示する機能を実装しています。
・上記補完処理が成功した場合、コードを含む全カラムの情報を付属情報として保持する
・補完処理実行後、補完に成功したかどうかをイベントでハンドリング可能
　　　補完成功時は、イベントから付属情報を取得可能です
・コード一致以外にも固定検索条件を追加設定可能
・「マスタ検索ダイアログ」を表示して、一覧からコードを選択することが可能
　　　　マスタ検索ダイアログは、反映先のフィールドの検索条件を引き継ぎます

【グリッド用追加機能】
カラム（グリッド）の場合は下記機能が追加されます
・カラム単位での一括補完処理
・固定検索条件以外に、レコード単位での検索条件が設定可能

■サンプルの内容説明
・「...」と表記されているボタンを押すと、社員マスタのコード検索ダイアログが表示されます
　　一覧から任意のレコードを選択すると、フィールドにコードと名称が反映されます
　　
・「社員コードテキストフィールド」に U0001 と入力すると、
　　社員マスタテーブルから、対応する社員情報を取得し、名称を補完表示します
　　同時に、その社員が退職している（RSG_DT!=99999999）場合は、退職と表示します
　　
・テキストフィールドと同様に、「社員コードカラム」のいずれかのセルに U0001 と入力すると、
　　同レコードの名称セルに名称を補完表示します
　　退職判断についてもテキストフィールドと同様です
　　
・チェックボタンの「固定条件「等級=A1」」をチェックすると、
　　テキストフィールド、グリッドともに、
　　役職等級（GRD_CD）がA1の社員のみ検索されるようになります
　　
・グリッドでは、チェックボタンの「レコードごとの条件「部門=SCT_CDフィールドの値」」をチェックすると、
　　レコードごとに「部門（条件）」カラムに入力された値を、
　　部門コード（SCT_CD）の検索条件として利用します
　　（DBでは、各社員に、123, 234, 999という3つの部門コードを設定しています）

・「補完」ボタンを押すと、グリッドにU0001からU0013までのコードを反映し、
　　全レコードに対して補完処理を一括で行います

・「フィールドの付属情報取得」ボタンを押すと、「社員コードテキストフィールド」
　　社員コードに関連して保持されている付属情報を一覧表示します
・「選択レコードの付属情報取得」ボタンを押すと、グリッドで選択されているレコードを対象に、
　　社員コードに関連して保持されている付属情報を一覧表示します

・画面下部の「社員マスタテーブル全件取得」ボタンを押すと、
　　社員マスタテーブルに登録されている全レコードを取得、表示します。
　　カラム名は、テーブルに設定されている物理名となります

サンプルでは、DBにSQLite を利用しているので、面倒なサーバ、DBの設定等は不要ですが、
実際には、環境に合わせてアプリケーションサーバ、DBサーバを利用することになると思います。
私が担当したプロジェクトは、サーバ側をJavaで実装し、クライアント・サーバ間の接続はCurl ORBを利用、
サーバからDBへの接続はO/Rマッパの「iBatis（MyBatis）」を利用する、
という環境が多かったため、同等の環境構成での利用を想定したプレームワークとなっています。

今回のサンプルではチェック機能を実装してませんが、
過去に投稿した、入力チェックのフレームワークと組み合わせれば、
「入力したコードが、マスタに存在しなければエラーとする」といった振る舞いを実装することも可能です。

　　■入力チェックのフレームワーク
　　http://communities.curl.com/showthread.php?tid=1078

また、今回のサンプルでは、マスタテーブル内の値と一致させる単純検索条件のみですが、
SQLのフォーマットを変更することで、
たとえば、部門Ａもしくは部門Ｂに所属する社員を検索する、
といった複合的な条件も利用可能です。
この辺りは、iBatis（MyBatis）などのO/Rマッパを利用することで効率よく開発できると思います。

なお、サンプル内で利用しているSQLiteでの「社員マスタ」の操作については、
前回の投稿と同じプログラムを利用しています。
「社員マスタ」のテーブル情報などは、そちらを参照してください。

　　■CurlでSQLite を使ってみよう
　　　http://communities.curl.com/showthread.php?tid=1086

マスタ検索.zip (Size: 103.53 KB / Downloads: 964)

CurlでSQLite を使ってみよう

Thu, 22 May 2014 10:18:16 +0000

★point
　ローカルでデータベースを試したいなら SQLite を使ってみよう

業務アプリ開発では避けて通れないのがデータベース（DB）。
DBといえば、有料であればOracle、無料であればMySQL、PostgreSQL 等が有名どころですが、
サーバを用意したり、接続の設定をしたり、始めるまでにはいろいろ面倒。

簡単にローカル環境でいろいろ試したいなら、SQLite を利用するというのはどうでしょう。

Curlであれば、SQLiteと接続するためのオープンソース「Curl Data Kit（CDK）」を使って、
面倒な設定なしでSQLiteを利用できます。

添付したサンプルでは、この「CDK」を使て、社員マスタのテーブルをクリエイトしたり、
レコードの追加・削除などの処理を行えます。
（CDK も含まれているので、別途ダウンロードする必要はありません）

説明:
アプレット初回起動は、「社員マスタ」が存在しないため、エラーメッセージが表示されます。
起動後、画面上部の「create EMP_MST」ボタンを押すと、社員マスタ（EMP_MST テーブル）が作成されます
　※テーブルは、アプレットと同じフォルダにある、test.db というSQLite のファイルに作成されます
「insert EMP_MST」ボタンを押すと、プログラムで定義している社員のレコードが追加されます

■サンプル内で利用している「社員マスタ」テーブルの属性情報
テーブル名：EMP_MST
カラム（説明、物理名、型）
　社員コード　　　EMP_CD　CHAR(5)　※プライマリキー
　社員名　　　　　EMP_NM　CHAR(20)
　所属部門コード　SCT_CD　CHAR(10)
　役職等級コード　GRD_CD　CHAR(2)
　退職年月日　　　RSG_DT　NUMBER(8)　※在職者の値は99999999

最近はモバイルアプリでの利用でも注目を集めているようですので、
ご興味のある方は、SQLiteを触ってみるとよいかもしれません。

■「CodeZine」記事：
　Curlのオフライン機能とSQLiteを使って「停止しないシステム」を作る
http://codezine.jp/article/detail/5027

■技術情報サイト
　クライアント・データベース操作（SQLite）
http://developers.curlap.com/re-referenc...qlite.html

■SourceForge Curl Data Kit（ダウンロードはここから）
http://sourceforge.net/projects/curl-cdk/

■SQLite入門
http://www.dbonline.jp/sqlite/

■SQLite データベース・ブラウザ (SQLite Database Browser)
http://www.kkaneko.com/rinkou/sqlite/sql...owser.html

SQLite.zip (Size: 41.35 KB / Downloads: 1013)

セッションをより確実に殺す（Oracle編）

Mon, 19 May 2014 08:08:57 +0000

★point1
　通常は ALTER SYSTEM KILL SESSION で殺す
★point2
　だめなら orakill コマンドで殺す

以前、あるSQLの実行結果が、DBサーバから戻ってこない、という問題が起きた際、
原因となっているDBのセッションを殺す、ということを行いました。

通常、私は、SQL Developer を使っているので、[ツール]->[セッションのモニター]で、
SYSDBA権限を持った接続を開き、[WAIT_SECONDS]の値が大きくなっているレコードを、
右クリックメニューの[セッションの中断]を選んで消しています。
（ALTER SYSTEM KILL SESSION と同等）

ただ、この操作をしたときに、下記のような例外が起こり、
即座にセッションがキルされない、ということが何度もあります。
この例外が発生すると、セッションのレコードで STATUS が、KILLED にはなるのですが、
しばらく（数時間以上）経っても、レコードが残り続ける状態になってしまいます。

■セッションキル時に発生する例外
リクエストされた操作の実行中にエラーが発生しました:

ORA-00031: セッションは強制終了されます。
00031. 00000 - "session marked for kill"
*Cause: The session specified in an ALTER SYSTEM KILL SESSION command
cannot be killed immediately (because it is rolling back or blocked
on a network operation), but it has been marked for kill. This
means it will be killed as soon as possible after its current
uninterruptable operation is done.
*Action: No action is required for the session to be killed, but further
executions of the ALTER SYSTEM KILL SESSION command on this session
may cause the session to be killed sooner.
ベンダー・コード31

こうなってしまうと、何度同様の手順でセッションを殺そうとしても、同じエラーが出るだけで、
セッションが残り続けてしまい、
それだけならまだしも、ほかに何の処理をしていなくても、
この、KILLEDになったセッションがいるだけで、DBサーバのCPU利用率が50%を超えた状態が続いてしまう、という状況でした。

エラー内容を読む限り、ロールバック等の処理をおこなってからセッションが切られます、ということのようですが、
対象のSQLはSELECT文なので、ロールバックする処理はないはずです。

なぜにセッションが残ってしまうのか、原因はわからないのですが、
とりあえず、ALTER SYSTEM KILL SESSION よりさらにアクティブにセッションを殺す方法として、
orakill コマンドというものがあったので、下記に備忘録を残しておきます。
あまり推奨されていないコマンドのようなので利用には注意が必要かも、です。

■orakillコマンド
orakill sid（※１） thread（※２）
※１：対象DBのサービスID　セッションID（v$session.sid）ではないことに注意
※２：プロセスID（v$process.spid）

■orakill コマンドに必要なSPIDを特定するためのSELECT文
select spid, s.sid, s.serial#, s.status , osuser, s.program,s.username, s.event from
v$process p, v$session s where p.addr=s.paddr and s.status = 'KILLED';
（STATUSが「KILLED」になっているプロセスIDを確認

■参考　[Oracle]強制終了したセッションが「killed」で残ってしまう場合の対処方法
http://www.popolog.net/articles/2013/04/..._kill.html

RecordGridColumnの配列は、フィールドで定義するな

Fri, 16 May 2014 10:21:58 +0000

★point
　RecordGrid.columns に設定するRecordGridColumnの配列は、フィールドで定義するな！

下記の数値は、RecordGridUI.get-cell-at で、
１回につき、100レコード×100カラムのセルを取得した場合の、
メモリの使用量の推移です。
※Curlのメモリ使用量は、「タスクマネージャ」の「プロセス」タブで表示される
　「surge,.exe」の「メモリ（プライベートワーキングセット）」を参照しました

■セル取得時のメモリ使用量
①「field定義のカラムを利用」した場合のメモリ消費量（単位は100KB）
1回目： 508 差分
2回目： 791 283
3回目：1074 283
4回目：1347 273
5回目：1629 282
6回目：1894 265
7回目：2195 301

②「一時的なカラムを利用」した場合のメモリ消費量（単位は100KB）
1回目： 549 差分
2回目： 791 242
3回目：1075 284
4回目：1347 272
5回目：1367 20
6回目：1383 16
7回目：1407 24

①と②の違いは、下記のアプレットのコードを見てもらうとわかりますが、
簡単に言うと、RecordGrid.columns に設定する{Array-of RecordGridColumn} を、
クラスのフィールド（field）に定義して利用するか、そうでないか、というものです。

Code:
{define-class public Screen {inherits Dialog}

  ||レコードとカラムの数

  field rs-size:int = 100

  field rf-size:int = 100

  ||フィールドとして定義するレコードグリッドカラムの配列

  field ary-column:{Array-of RecordGridColumn}

  ||一時的なレコードグリッドカラムの配列を返却するゲッター

  {getter {tmp-ary-column}:{Array-of RecordGridColumn}

    {return {self.make-columms}}

  }

  {constructor public {default}

    set self.ary-column = {self.make-columms}

    def ary-rf = {{Array-of RecordField}}

    {for i:int = 0 below self.rf-size do

        {ary-rf.append

            {RecordField {String i}, nullable? = true}

        }

    }

    def rs =

        {RecordSet

            {RecordFields {splice ary-rf} }

        }

    {for i:int = 0 below self.rs-size do

        def new-r = {rs.new-record}

        {rs.append new-r}

    }

    def cb-permanent =

        {CommandButton

            label = "field定義のカラムを利用する",

            {on Action do

                {self.get-cell rs, self.ary-column}

            }

        }

    def cb-tmp =

        {CommandButton

            label = "一時的なカラムを利用する",

            {on Action do

                {self.get-cell rs, self.tmp-ary-column}

            }

        }

    def cb-gc =

        {CommandButton

            label = "ガベージコレクト",

            {on Action do

                {garbage-collect}

            }

        }

    {self.add

        {VBox

            cb-permanent,

            cb-tmp,

            cb-gc

        }

    }

  }

  ||セルを取得すrう

  {method {get-cell

              record-set:RecordSet,

              cols:{Array-of RecordGridColumn}

          }:void

    let cnt:int = 0

    def grid = {RecordGrid }

    set grid.columns = cols

    set grid.record-source = record-set

    {for r in grid.records do

        {for col in grid.columns do

            def cell = {grid.ui.get-cell-at r, col}

            {if-non-null cell then

                set cnt = cnt + 1

             else

                {output "cell が見つかりません"}

            }

        }

    }

    {output cnt & "個のセルを生成しました"}

  }

  ||大量のカラムを生成する

  {method {make-columms}:{Array-of RecordGridColumn}

    def cols = {{Array-of RecordGridColumn}}

    {for i:int = 0 below self.rf-size do

        {cols.append

            {RecordGridColumn {String i}}

        }

    }

    {return cols}

  }

}

{def s = {Screen}}

{value s}

数値の推移をみてもわかるように、フィールドで定義して利用した①には、
単純増加傾向がみられるのに比べ、
そうではない②は、4回目以降、メモリの使用増加量が低下しています。
①については、私が試した限りでは20回以上、単純増加傾向か続きました。

また、各処理の間で、明示的に「ガベージコレクト（garbage-collect）」を呼び出した場合も、
①ではその効果がみられませんでした。
プログラムでは、グリッドを毎回作り直しているので、
以前のグリッド内で生成されたセルは、ガベージとして認識され、破棄されてほしいところですが、
私の試した限りでは、そのように期待した結果にはなりませんでした。

どうも、フィールドで定義したカラムを利用して生成されたセルは、
そのフィールドの親クラスが破棄されるまで、
ずっとガベージとして認識されないのではないかと推測されるのです。

静的に、グリッドとカラムを保持するような画面であればよいのですが、
グリッドに対して何度もカラムの再設定をする処理のある画面では、
上記のように、メモリの使用量がどんどん増えてしまう、
という問題が起こる可能性があります。

今回私が試した環境は、Windows7+Curl8.0.4 だけですので、
この現象が、ほかの環境でも発生するかは不明ですが、
できるだけ、RecordGridColumn の配列は、フィールドで定義せず、
記載したアプレットのサンプルソースのようにgetterで一時的に作成するなどの方式にしたほうがよさそうです。

CSVデータをDTOに詰めてはいけない

Tue, 13 May 2014 07:09:01 +0000

★point
　CSVデータをDTOに詰めてはいけません、絶対に。

今回は、Java に詳しい方には、「そんなの当然」といわれてしまいそうな話なのですが、
Curl ORB を利用して、サーバからCSVデータをダウンロードしたい、という場合、
私などは、CSV形式に整形した文字列を、DTOのフィールドに詰めて、
クライアント側でその値を、ファイル出力（write-to）すればいいじゃん、と簡単に考えてしまいます。

しかし、サーバのメモリは有限なので、CSVデータの容量や、同時利用人数によっては、
CSVデータのためのメモリが確保できず、OutOfMemory 例外が出てしまう可能性があります。
実際にこれで痛い目にもあいました。

この問題を回避するためには、下記のような処理を実装する方法が考えられます。
①サーバでは、CSVデータを、テンポラリとして実ファイルに出力する ※１、２
②サーバからクライアントに、①で出力したファイルの「パス」をDTOのフィールドに詰めて返却する※３
③クライアントは、受け取ったファイルパスからファイルをダウンロードする ※４、５

注意
　※１：出力前のCSVデータ自体の確保でOutOfMemoryが出ないように注意すること
　　　　具体的には、DBから取得したデータをまとめてリストで保持するのではなく、
　　　　たとえば、FETCHデータを１行ごとファイルへ追記出力するなどの処理が必要
　　　　（iBatis であれば、RowHandler を利用して、１行ごとに処理することが可能）
　　　　　■参考「メモリー管理に失敗したJavaアプリの実例」
　　　　　http://thinkit.co.jp/story/2011/03/11/2051
　※２：テンポラリファイルのパスは、クライアントからhttpでアクセスできるパスであること
　　　　また、ファイル名にはyyyymmdd_hhmmss+ミリ秒をつけて、同時利用時でもファイル名が衝突しないように注意
　※３：テンポラリのファイルパスとは別に、クライアントで保存する際の初期提案用ファイル名も必要
　※４：ファイルダウンロード時の例外ハンドリング、
　　　　保存ダイアログの初期表示フォルダを指定する機能なども実装すること
　※５：サーバで実行される日時バッチなどを組み、定期的にテンポラリファイルを削除する機能を実装すること

もちろん、サーバのメモリが潤沢であったり、出力するCSVデータ容量が極小であったり、
DTOに詰めてやり取りしても問題がない場合はあるので、
上記のような、やや面倒な実装を忌避したくなる気持ちは十分すぎるほどわかります。
しかし、データは肥大化していくものですので、
運用開始直後は問題なく動いていても、ダウンロードの対象データが大きくなるにつれ、
ある時から急に問題が発生するようになる、ということも考えられます。

アプリケーションの将来性を考えるうえでも、
企業で利用するアプリケーションの基盤としては、
絶対に「DTOのなかにCSVを詰めない」という方針を取ったほうが良いと思っています。

DBからSQLの結果が返ってこない

Fri, 09 May 2014 11:43:43 +0000

★point
　Oracle では、SQLのサイズを64kバイト未満に抑えよう

ある案件で、ある損益帳票を、社内の全部門で集計する、という処理が、
固まってしまう、という問題が起きました。

現象としては、Javaから、iBatis経由でSQLをOracleに発行した後、
DBサーバのCPU利用率が100%にまで上がってしまい、
結果が返ってこなくなる、というものでした。

この時に発行されているSQLは、IN句のなかに数百の部門が展開されるているもので、
数千行という、かなりの大きさになっていました。

また、返却されるデータ量も、数万件という、そこそこの件数なので、
そのあたりがDBサーバの負荷になっているのではないか、という予想のもと、
いろいろと調査をしたのですが、
下記のような矛盾があり、原因の特定ができず、困っていました。

・該当の処理も、必ず固まるわけではない（条件は特定できない）
・返却されるデータの大小にかかわらず、固まることがある
・同じSQLを、SQL Developer から投げると大きな遅延なく結果が返却される

いろいろと頭をお悩ませたのですが、最終的には、下記のサイトを見て、
どうやら、SQLの大きさに原因があるのではないか、ということに落ち着きました。
たしかに、固まるSQLとそれ以外のSQLの間には64kバイトの壁がありました。

■Oracle 性能限界
http://www.shift-the-oracle.com/oracle/limits.html
「SQLにおける制限事項」

（とはいえ、利用しているOracleのバージョンは11gなので、
　この64kバイト制限が9iまでの制限という情報とは矛盾があるのですが・・・）

結局、全部門をまとめてIN句に入れるのではなく、部門ごとのSQLを、
Javaでループしながら投げる、という方式に変更することで、
処理が固まることはなくなりました。

入力チェックのフレームワーク

Mon, 28 Apr 2014 09:19:28 +0000

★point
チェックは、コントロールとグリッドの両方で、同様の振る舞いをさせるべき

これまで、自分が参画したプロジェクトで、
Curl賢人の方々のソースも参考にしながら、
自分なりの入力チェック用のフレームワークを作ってきましたが、
いったん、シンプルなレベルに整理してみました。

このフレームワークは、コントロールとグリッド（セル）のチェックと、
その結果の振る舞いに差異がないようにしたい、というポイントを意識しています。
そのため、「グリッドのエラー状態を保持」できるようにしています。

■プログラム概要
「入力不可（read-only）」「必須（required?）」「エラー状態（error?）」のプロパティを持つ
チェックルールは、「編集仕様（EditorSpec）」で定義する

■主な振る舞い
「入力不可」に設定すると、背景色がグレーになり、キー入力が行えない
「必須」に設定すると、背景色が黄色になり、チェック時に値が空文字だとエラーになる
「エラー状態」が活性状態の場合、背景色が赤色になる

賢人の方々からすると、突っ込みどころも多いかと思いますので、
ぜひコメントいただけるとありがたいです。

Validate.zip (Size: 126.16 KB / Downloads: 1010)

Curl アプレットを同期させるための注意点

Tue, 22 Apr 2014 07:22:29 +0000

★point1
　resync-file を利用しよう

★point2
　デプロイモジュールの更新日時を変更しよう

Curl アプレットは、クライアント側にキャッシュされることで、毎回の起動時にロード時間を短縮してくれます。
さらに、それらのキャッシュは、起動時に自動でサーバに上がっているモジュールと比較され、
差分がある場合は、最新のモジュールがキャッシュされる仕組みになっています。

とはいえ、正しい設定、環境でないと、このキャッシュ更新機能がうまく働かないので、
いくつか注意するすべき項目を挙げておきます。

①resync-file を利用
②デプロイ時に各ファイルの更新日時を最新化する

①については、過去のCurlアプレット配信では resync-as-of というAPIを利用して
最新化の日時を設定していた方もいらっしゃるかと思いますが、
このAPIは、デプロイの度に対象日時を変更する必要があり、ちょっと面倒でした。
現在は、「resync-file」を利用することで、manifest.mcurl ファイルの更新日時が
自動的に対象日時として設定されます。
Curl としても、このresync-file を利用することを推奨しているようです。

②については、結構見逃されがちな問題なので、注意が必要です。
具体的には下記のような例があります。

■ケース１
resync-file を使っており、再デプロイ時に変更のあったパッケージのみ pcurl化し、
すでに運用されているアプリケーションから、そのファイルだけ、元ファイルと置き換えた。
しかし、次の日起動したら同期化されていなかった。
　→理由：manifest.mcurl の更新日時がそのままなので、変更があると判断されない。

■ケース２
すでに運用されているアプリケーションを最新化するため、
デプロイ当日の12時に、デプロイモジュールを事前に作成しておき、
実際のデプロイは20時に行った。
ユーザは、当日の15時に初めてアプリケーションを起動していた
しかし、次の日起動したら同期化されていなかった
　→理由：デプロイされたファイルの更新日時（12時）が、
　　　　　キャッシュされた時刻（15時）より過去になってしまうため。

Curlの同期ルールを正確に理解したうえで
デプロイモジュール作成時のタイミングや、作成モジュール対象のファイルの切り分けを行えば、
これらの問題を起こさずに済みますが、
私の場合は、「全ファイルの更新日時を一括してデプロイ時刻に統一する」のが一番楽かな、
と思っています。

デプロイ時に Ant を使っているのであれば、 touch タスクで更新日時を変更するか、
ツールなどを利用して、デプロイ直前に更新日時を変更してからデプロイすれば
上記の問題は回避できます。

■（参考）ファイルのアクセス日付変更ツール
http://www.vector.co.jp/soft/dl/winnt/ut...03248.html

Curl RTE のインストールログの取得方法

Fri, 18 Apr 2014 10:49:29 +0000

★point
インストール失敗時は、ログをとって検証！

私個人は、Curl RTE のインストールでコケたことがないのですが、
数百人、数千人という単位でお客様にインストールしてもらう際には、
時々インストールに失敗した、という報告を受けることがあります。

大体の場合は、アドミン権限がなかったり、再インストールしたらうまくいった、という結果なのですが、
よくわからない場合は、ログを取る方法がよさそうです。

msiexec /i curl-rte-8.0.3-ja.msi /l*v ./logfile.txt

上記のようなコマンドで、ログファイルの出力が可能です。